Comando tapparelle temporizzato con Arduino

ArduinoCopia

/*
   Comando Tapparelle
   Version 1.0 2021
   Copyright 2021 Sgart.it
   https://www.sgart.it/
   Board: 'Arduino UNO'
   Port: COM7
*/
#include <arduino-timer.h>

const String VERSION_STR = "Comando Tapparelle Manuale v. 1.2021-07-10 - Sgart.it";

/*
 * Definizione IO
 */
const byte RELE_UP = 2; // relè salita - Arduino GPIO pin to use. (D2).
const byte RELE_DOWN = 3; // relè discesa - Arduino GPIO pin to use. (D3).

const byte BUTTON_UP = 5; // pulsante salita - Arduino GPIO pin to use. (D5).
const byte BUTTON_DOWN = 6; // pulsante discesa - Arduino GPIO pin to use. (D6).

/*
 * variabili
 */
// memoria stato pulsanti, true = premuto
boolean  buttonUp = false; 
boolean  buttonDown = false;

boolean  buttonUpPrev = false; 
boolean  buttonDownPrev = false;

// memoria autoritenuta relè
boolean  timerReleUp = false; 
boolean  timerReleDown = false;
boolean  timerButtonDisabled = false;

// coando relè
boolean  releUp = false; 
boolean  releDown = false;

/*
 * Timer
 */
const int TIMER_RELE_ON_MILLISEC = 30000; // 30 sec, timer tapparella
const int TIMER_BUNTTON_DISABLED_MILLISEC = 200; // 0,2 sec const int TIMER_BUNTTON_DISABLED_MILLISEC = 250; // 0.25 sec, antirimbalzo pulsanti
 
Timer<2, millis> timer; // inizializzo i 2 timer

auto timerOut = timer.in(1, [](void*) -> bool { return false; });
auto timerButton = timer.in(1, [](void*) -> bool { return false; }); 

bool handleTimerOut(void *argument) {
  Serial.println("Timer timerOut fine");
  // timer.cancel(timerOut);
  timerReleUp = false;
  timerReleDown = false;
  setRele();
  return false;
}

bool handleTimerButton(void *argument) {
  Serial.println("Timer timerButton fine");
  // timer.cancel(timerButton);
  timerButtonDisabled = false;
  return false;
}


/*
 * Setup
 */
void setup() {
  Serial.begin(115200);
 
  Serial.println("\nSet pin ...");

  // conigurazione output
  pinMode(RELE_UP, OUTPUT);
  digitalWrite(RELE_UP, HIGH);
  
  pinMode(RELE_DOWN, OUTPUT);
  digitalWrite(RELE_DOWN, HIGH);

  // configurazione input con resistenza di pullup
  pinMode(BUTTON_UP, INPUT_PULLUP);
  pinMode(BUTTON_DOWN, INPUT_PULLUP);

  Serial.println(VERSION_STR);
}

/*
 * Loop
 */
void loop() {
  // gestione timer
  timer.tick();

  // lettura diretta ingressi/pulsanti
  bool pinUp = digitalRead(BUTTON_UP) == LOW;
  bool pinDown = digitalRead(BUTTON_DOWN) == LOW;

  // impulso / fronte di salita pulsanti
  bool pulseUp = pinUp == true && buttonUpPrev == false;
  bool pulseDown = pinDown == true && buttonDownPrev == false;
  

  // logica pulsanti
  buttonUp = timerButtonDisabled == false && pulseUp;
  buttonDown = timerButtonDisabled == false && pulseDown;

  if(pulseUp || pulseDown) {
    Serial.print("Pulse up: ");
    Serial.print(pulseUp);
    Serial.print(", down: ");
    Serial.println(pulseDown);

    if( timerButtonDisabled == false) {
      Serial.println("Start timerButtonDisabled");
      timerButtonDisabled = true;

      timer.cancel(timerOut);
      timer.cancel(timerButton);
      
      timerButton = timer.in(TIMER_BUNTTON_DISABLED_MILLISEC, handleTimerButton);
    }

    auto active_tasks = timer.size();
    Serial.print("Task nr: ");
    Serial.println(active_tasks);
  }
  
  // se premo entrambi i pulsanti (PIN), oppure ho entrambe le ritenute, spengo tutto (sicurezza)
  if((pinUp && pinDown) || (timerReleUp && timerReleDown)) {
    Serial.println("Entrambi i pulsanti, reset");
    resetAll();
  }

  // se premo uno dei i pulsanti durante l'autoritenuta, spengo tutto (sicurezza)
  if((buttonUp || buttonDown) && (timerReleUp || timerReleDown)) {
    Serial.println("Autoritenuta e pulsanti, reset");
    resetAll();
  }

  // se ho il pulsante premuto attivo l'autoritenuta (timer alla diseccitazione)
  if(buttonUp || buttonDown) {
    if(timerReleUp == true || timerReleDown == true) {
      Serial.println("Timer già attivo");
    } else {
      timerOut = timer.in(TIMER_RELE_ON_MILLISEC, handleTimerOut);
      timerReleUp = buttonUp == true;
      timerReleDown = buttonUp == false;
    }
  }

  // attivazione relè
  releUp = (buttonUp || timerReleUp) && releDown == false;
  releDown = (buttonDown || timerReleDown) && releUp == false;

  setRele();

  // memorizzo stato precedente pulsanti
  buttonUpPrev = pinUp;
  buttonDownPrev = pinDown;
}

void resetAll(){
    Serial.println("Reset");
    // spengo il timer
    timer.cancel(timerOut);
    timerReleUp = false;
    timerReleDown = false;
        
    buttonUp = false;
    buttonDown = false;

    releUp = false;
    releDown = false;

    setRele();
}

void setRele(){
  digitalWrite(RELE_UP,releUp ? LOW : HIGH);
  digitalWrite(RELE_DOWN, releDown  ? LOW : HIGH);
}